Coupled Cavity Part 1 Tutorial

Derive the expressions for a coupled cavity using a compound Fabry-Perot cavity

Fabry-Perot functions

ϕ = single pass phase
ri = input mirror reflectivity of FP (assuming minus reflectivity inside the cavity)
re = end mirror reflectivity of FP (again assuming minus reflectivity inside the cavity)
Here I on purpose leave the negative sign out of the exponential, 
although it should be there, because mathematica prefers positive exponentials and will simplify weird without them.
We’ll need to remember to set ϕ -> -ϕ  at the end of this for the plots

refl[ϕ_,ri_,re_]:=((ri-re Exp[I 2ϕ])/(1-ri re Exp[I 2 ϕ]));
gain[ϕ_,ri_,re_,ti_]:=(ti/(1-ri re Exp[I 2 ϕ]));
trans[ϕ_,ri_,re_,ti_,te_]:=((ti te Exp[I ϕ])/(1-ri re Exp[I 2 ϕ]));

Tutorial Answers

1. Write the second cavity reflectivity, gain, and transmission expressions r((Subscript[ϕ, 2])), g((Subscript[ϕ, 2])), t((Subscript[ϕ, 2])).

r23=refl[ϕ2,r2,r3]
g23=gain[ϕ2,r2,r3,t2]
t23=trans[ϕ2,r2,r3,t2,t3]

2. Write the compound cavity reflectivity, gain, and transmission expressions r(ϕ1, ϕ2), g1(ϕ1, ϕ2), t(ϕ1, ϕ2) in terms of r1, t1, ϕ1, and your expressions from (1)

Here I use the subscript (Subscript[r, 23]), as opposed to r23 above, to allow for the variable representation.
Notice that we have just stacked the usual Fabry-Perot equations, but subbed in (Subscript[r, 23]) and (Subscript[t, 23]) everywhere.

There is a very sneaky minus sign I’ve put in here, the -(Subscript[r, 23]) in all the calls to the functions.
This is because, in the Fabry Perot functions defined above, we have assumed that the mirrors on the interior of the cavity inflict a sign flip (i.e. have a minus sign), while the reflections outside the cavity are positive.
To recover a plus sign reflection on the interior of the Fabry Perot, I must use -(Subscript[r, 23]) in my FP function calls.
Notice that this gives us the unusual denominator with a plus sign: (1 + (Subscript[r, 1])(Subscript[r, 23]) (e^(2 i ϕ1)))

rr=refl[ϕ1,r1,-(Subscript[r, 23])]
g1=gain[ϕ1,r1,-(Subscript[r, 23]),t1]
tt=trans[ϕ1,r1,-(Subscript[r, 23]),t1,(Subscript[t, 23])]

3. Expand out your terms for r(ϕ1, ϕ2), g1(ϕ1, ϕ2), t(ϕ1, ϕ2), to get the full expressions in terms of r1, r2, r3, t1, t2, t3, ϕ1, ϕ2.

I’ll do a substitution of the evaluated r23 for the variable (Subscript[r, 23]), 
and t23 for (Subscript[t, 23]), then expand.
cc suffix below stands for coupled cavity.

params={(Subscript[r, 23])->r23,(Subscript[t, 23])->t23};
reflcc=Simplify[rr/.params]
gain1cc=Simplify[Together[g1/.params]]
transcc=Simplify[tt/.params]

4. How might you derive the amplitude gain for the second cavity g2(ϕ1, ϕ2)?

There are several ways to go about it, 
the simplest is to realize that you’ve got almost all the way there with the g1(ϕ1,ϕ2) calculation, 
you just need to multiply g1(ϕ1,ϕ2) by a single-pass phase of the first cavity ϕ1, then the Fabry-Perot gain g(ϕ2) we calculated in Part 1.

gain2cc=Simplify[gain1cc Exp[I ϕ1] g23]

Another way is to instead compound the first two mirrors to form an r12 and t12, then use those to calculate the coupled cavity gain in the second cavity.
Remember to use -r2, to account for the positive reflection we get from reflection off the middle mirror from the left!
This again should give us the “unusual denominator” with a plus sign.

r12=refl[ϕ1,r1,-r2]
g12=gain[ϕ1,r1,-r2,t1]
t12=trans[ϕ1,r1,-r2,t1,t2]
gain2cc2=Simplify[gain[ϕ2,r12,r3,t12]]

Final way would be explicit adjacency matrix.  Exercise left to the reader.

5. What should the phases for ϕ1 and ϕ2 be to maximize carrier power in the arm cavity?

Starting with the arm cavity, ϕ2 must be zero, 
so we can get the resonant buildup inside the arm according to g(ϕ2) = (t2/(1-r1 r2 Exp[I 2 ϕ]))

g23/.{ϕ2->0}

Next, let’s consider the compound interferometer expression for the gain of the first cavity

g1

To figure this out, we might instinctively think we need ϕ1 =0 as well, but remember that (Subscript[r, 23]) is complex and can be either positive or negative.
We have to think about the sign of the reflection off the arm cavity r(ϕ2) when ϕ2 = 0:

r23/.{ϕ2->0}

The reflection actually flips sign based on how reflective the mirrors r2 and r3 are.
For our case in Advanced LIGO, T3 = 5 ppm, and T2 = 1.5%, so r3 > r2.
This means that (Subscript[r, 23]) will be negative at resonance.
This negative sign flips the denominator of g1(ϕ1) = (t1/(1 + (e^(2 i ϕ1)) r1 (Subscript[r, 23]))), so ϕ1 = 0 will give us our resonant gain boost.

So, in the end, ϕ1 = 0 is the correct value to keep carrier on resonance in the entire coupled cavity, given Advanced LIGO’s mirror reflectivities.
This gives us the following cavity gain expressions

gain1cc/.{ϕ1->0,ϕ2->0}
gain2cc/.{ϕ1->0,ϕ2->0}

The (lossless) power gain values below are subbed in to give us
1) Arm Gain
2) Power Recycling Gain (PRG)
3) Total CARM gain = (Power Recycling Gain) × (Arm Gain)

values={ϕ1->0,ϕ2->0,T1->0.031,T2->0.015,T3->5 (10^(-6)),r1->(Sqrt[1-T1]),r2->(Sqrt[1-T2]),r3->(Sqrt[1-T3]),t1->(Sqrt[T1]),t2->(Sqrt[T2]),t3->(Sqrt[T3])};
((Abs[g23])^2)//.values
((Abs[gain1cc])^2)//.values
((Abs[gain2cc])^2)//.values

6. What should the phases for ϕ1 and ϕ2 for the sidebands in the coupled cavity?

Again starting with the arm cavity, we want the sidebands to be antiresonant in the arm cavity, so ϕ2 must be (π/2), 
This stems from g(ϕ2) = (t2/(1-r1 r2 Exp[I 2 ϕ])).  
We need the denominator to be large, so the gain is small.
This means Exp[I 2 ϕ] = -1 is our desired setpoint, which means we must have ϕ2 = (π/2):

g23/.{ϕ2->(π/2)}

So now we have the arm’s phase setting so the sidebands do not resonate there.
But we want the sidebands to still resonate inside the first cavity.
What does this mean for ϕ1?

Again, consider the arm reflectivity term r(ϕ2), but this time let ϕ2->(π/2).

r23/.{ϕ2->(π/2)}

The reflectivity off the arm is positive.
This is different than before, with carrier.  
Now, again consider the gain of the full coupled cavity inside the first cavity:

g1

With us wanting resonance inside this cavity, we need the denominator (1+(e^(2 i ϕ1)) r1 (Subscript[r, 23])) as small as possible.
With (Subscript[r, 23]) being positive, that means that (e^(2 i ϕ1))= -1 is desired.
Again, this leads us to ϕ1 = (π/2). 
This restores resonance for the sideband inside of the first cavity, despite being antiresonant inside the second cavity.

This gives us the following gain expressions:

gain1cc/.{ϕ1->(π/2),ϕ2->(π/2)}
gain2cc/.{ϕ1->(π/2),ϕ2->(π/2)}

These are similar to carrier, but with some significant sign flips in the denominator that lead to less power buildup in the arms.
To demonstrate, let’s substitute in the Advanced LIGO values again
1) RF Sideband Arm Gain ( should be < 1 )
2) Power Recycling Gain (PRG) ( should be >> 1 )
3) Total CARM gain = (Power Recycling Gain) × (Arm Gain) ( should be < 1 )

values2={ϕ1->(π/2),ϕ2->(π/2),T1->0.031,T2->0.015,T3->5 (10^(-6)),r1->(Sqrt[1-T1]),r2->(Sqrt[1-T2]),r3->(Sqrt[1-T3]),t1->(Sqrt[T1]),t2->(Sqrt[T2]),t3->(Sqrt[T3])};
((Abs[g23])^2)//.values2
((Abs[gain1cc])^2)//.values2
((Abs[gain2cc])^2)//.values2

7. Find the coupled cavity pole (Subscript[ω, cc]) for carrier.

Find the denominator for the electric field solutions.  Print e.g. the second cavity gain:

gain2cc

denom=1+(E^(2 I ϕ1)) r1 r2-(E^(2 I (ϕ1+ϕ2))) r1 r3-(E^(2 I ϕ2)) r2 r3

Substitute in ϕ1 -> 0 and ϕ2 -> (((Subscript[ω, cc])(Subscript[L, 2]))/c), 
set the denom = 0, then solve for (Subscript[ω, cc]).

soln=Solve[(denom/.{ϕ1->0,ϕ2->((ωcc L2)/c)})==0,ωcc]
ωcc0=I soln[[1,1,2]]/.{(C[1])->0}

Evaluate the coupled cavity pole in Hertz

((ωcc0)/(2π))//.values/.{L2->3994.5,c->3 (10^8)}

The coupled cavity pole for Advanced LIGO is 0.37 Hertz.  This is extremely low.  
This means that when locked, Advanced LIGO low-passes all laser frequency and intensity excursions faster than 0.37 Hz.
Also, the laser must be stabilized to better than 0.37 Hertz in order to resonate inside the LIGO interferometer.  
This is extraordinarily stable, and in some frequency regimes is the most stable laser in the world.